Antura Game Project

Mont Blanc et montagnes (fr_08) - Script ​

Educators & Designers: help improving this quest!

Comments and feedback: discuss in the Forum
Improve script translations: comment the Google Sheet
Improve Cards translations: comment the Google Sheet
Improve the script: propose an edit here

quest_start ​


// fr_08 | Mont Blanc
// 
type: panel
color: red
---
<<declare $step_base1 = 0>>
<<declare $step_base2 = 0>>
<<declare $step_base3 = 0>>
<<declare $step_base4 = 0>>
<<SetActive key_gold_intro false>>
<<SetActive key_gold_1 false>>
<<SetActive key_gold_2 false>>
<<SetActive key_gold_3 false>>
<<SetActive backpack false>>
<<SetActive scarf false>>
<<SetActive hat false>>
<<SetActive sunglasses false>>
<<SetActive crampons false>>
<<card alps>>
Bienvenue dans les Alpes françaises ! Les Alpes sont de hautes montagnes, dans le sud-est de la France. #line:start_1
<<card place_mont_blanc>>
Aujourd'hui, tu vas au sommet du Mont Blanc. C'est la plus haute montagne de France. #line:start_2
<<target npc_intro>>

quest_end ​


type: panel_endgame
color: red
---
<<card place_mont_blanc>>
Bravo ! tu es au sommet du Mont Blanc. Il mesure 4807 mètres. C'est la plus haute montagne de France. #line:end_1
Dans les Alpes, il y a beaucoup de grandes et belles montagnes. #line:end_2
<<jump post_quest_activity>>

post_quest_activity ​


type: panel
tags: proposal
color: red
---
Dans ton cahier, dessine le Mont Blanc et les drapeaux de la France, de la Suisse et de l'Italie. #line:post_1
<<quest_end>>

npc_intro ​


// ---------------------------------------
// INTRO
// ---------------------------------------
color: blue
group: intro
---
<<if has_item("backpack")>>
    Tu as ton sac à dos. Maintenant, va chercher les vêtements chauds et les affaires de montagne. #line:04c1c1f 
    <<card place_mont_blanc>>
    Monte en haut du Mont Blanc #line:0f4644b 
    <<card climbing>>
    Trouve les vêtements chauds et les affaires de montagne. #line:07f2699 
    <<SetActive door_intro false>>
    <<target npc_base_1>>
<<elseif GetCurrentTask() == "get_backpack">>
    Reviens quand tu as trouvé. #line:046eb33 
<<else>>
    <<card mountain_guide>>
    Aide-moi ! Je suis ton guide de montagne. Un chien bleu a pris tes affaires. #line:0724de3 
    Le chien est parti dans la montagne avec tes affaires. #line:01beb5e 
    <<camera_focus camera_mont_blanc>>
    Retrouve les vêtements chauds et les affaires de montagne. #line:0650acc 
    <<card backpack>>
    D'abord, tu as besoin d'un sac à dos. #line:045409f
    <<camera_focus camera_intro>>
    Ouvre le coffre pour trouver le sac à dos  ! #line:05cabb5 
    <<task_start get_backpack>>
    <<SetActive key_gold_intro true>>
<<endif>>

chest_intro ​


group: intro
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Le coffre s'ouvre ! Prends le sac à dos. #line:0c1f006 
    <<trigger chest_intro_open>>
    <<SetInteractable chest_intro false>>
    <<SetActive backpack true>>
<<else>>
    Le coffre est fermé à clé. Trouve la clé pour l'ouvrir. #line:chest_locked 
<<endif>>

item_backpack ​


group: intro
actor: 
color: yellow
---
<<card backpack>>
Dans le sac à dos, il y a de  l'eau, à manger et une carte. #line:05e80cb 
<<inventory backpack add>>
<<SetActive this false>>
<<action wear_backpack>>
<<task_end get_backpack>>
Maintenant, va dans la montagne. Trouve les vêtements chauds et les affaires de montagne. #line:029f39c
<<target npc_intro>>

npc_base1 ​


// ---------------------------------------
// Base 1 - The Valley's End
// ---------------------------------------
group: base_1
color: blue
---
<<if has_item("coat") and has_item("hat")>>
    Maintenant, tu es prêt. Tu peux aller au sommet du Mont Blanc ! #line:015bf8a
    <<camera_focus camera_snowman>>
    Le bonhomme de neige peut t'aider. Va le voir ! #line:showman_help
    <<camera_reset>>
    <<set $step_base1 = 1>>
    <<SetActive door_base_1 false>>
    <<target npc_base_2>>
<<elseif !has_item("coat")>>
    Tu n'as pas de manteau. Cherche le ! #line:03dd802 
    <<target coat>>
<<else>>
    <<card wind>>
    Il y a du vent. Il faut protéger tes oreilles. #line:b1_1
    Comment protéger tes oreilles ? #line:b1_q
    <<activity fr08_activity_1 activity_1_done>>
<<endif>>

activity_1_done ​


group: base_1
---
Ouvre le coffre pour trouver le bonnet  ! #line:0e83480 #task:get_hat
<<set $step_base1 = 1>>
<<task_start get_hat>>
<<SetActive key_gold_1 true>>
<<target chest_1>>

chest_base1 ​


group: base_1
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Le coffre s'ouvre ! Il contient du matériel. #line:056ec2b 
    <<trigger chest_1_open>>
    <<SetInteractable chest_1 false>>
    <<SetActive hat true>>
<<else>>
    Le coffre est fermé à clé. Trouve la clé pour l'ouvrir. #shadow:chest_locked 
<<endif>>

item_coat ​


actor: 
color: yellow
---
<<card coat>>
Avec un manteau, tu as chaud quand il y a du vent ou de la neige. #line:0e23f1f 
<<inventory coat add>>
<<SetActive this false>>

item_hat ​


actor: 
---
<<card hat>>
Avec un bonnet, tu n'as pas froid à la tête. #line:000fc05 
Le bonnet te protège du vent. #line:059d744
<<inventory hat add>>
<<SetActive this false>>
<<task_end get_hat>>
<<target npc_base_1>>
Continue à monter ! #line:0a7146f

npc_base2 ​


// ---------------------------------------
// Base 2 - Lower Mid
// ---------------------------------------
group: base_2
color: blue
---
<<if has_item("sunglasses") and has_item("gloves")>>
    Maintenant, tu es prêt. Tu peux aller au sommet du Mont Blanc ! #shadow:015bf8a
    Le bonhomme de neige peut t'aider. #line:fr08_b2_help
    <<set $step_base2 = 1>>
    <<SetActive door_base_2 false>>
    <<target npc_base_3>>
<<elseif GetCurrentTask() == "get_sunglasses">>
    Reviens quand tu as trouvé. #shadow:046eb33 
<<elseif !has_item("sunglasses")>>
    <<card sun>>
    Le soleil et la neige font mal aux yeux. Il faut des lunettes de soleil. #line:029a03e 
    <<card snow>>
    Qu'est-ce qui protège les yeux  ? #line:0a70f7d 
    <<activity fr08_activity_2 activity_2_done>>
<<elseif !has_item("gloves")>>
    Tu n'as pas de gants ! #line:06b3363 
    <<target gloves>>
<<else>>
    Continue à chercher. #line:keep_looking
<<endif>>

activity_2_done ​


group: base_2
---
Ouvre le coffre pour trouver les lunettes de soleil ! #line:0fdc3cb 
<<set $step_base2 = 1>>
<<task_start get_sunglasses>>
<<SetActive key_gold_2 true>>
<<target chest_2>>

chest_base2 ​


group: base_2
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Le coffre s'ouvre ! Prends les lunettes de soleil. #line:fr08_b2_chest 
    <<trigger chest_2_open>>
    <<SetInteractable chest_2 false>>
    <<SetActive sunglasses true>>
<<else>>
    Le coffre est fermé à clé. Trouve la clé pour l'ouvrir. #shadow:chest_locked
<<endif>>

item_gloves ​


actor: 
---
<<card gloves>>
Les gants protègent les mains. #line:0f2aac7 
A la montagne, il fait  froid #line:0d01879 
<<inventory gloves add>>
<<SetActive this false>>

item_sunglasses ​


actor: 
---
<<card ice>>
A la montagne, le soleil et la neige font mal aux yeux #line:02a2ea9 
<<card sunglasses>>
Les lunettes de soleil protègent les yeux. #line:088fb7f
<<inventory sunglasses add>>
<<SetActive this false>>
<<task_end get_sunglasses>>
<<target npc_base_2>>
Continue à monter ! #shadow:0a7146f

npc_base3 ​


// ---------------------------------------
// Base 3 - High-Mid
// ---------------------------------------
group: base_3
color: blue
---
<<if has_item("crampons") and has_item("rope")>>
    Tu as les affaires de montagne. Un dernier effort pour aller au sommet. #line:06b15bb 
    <<set $step_base3 = 1>>
    <<SetActive door_base_3 false>>
    <<target npc_base4>>
<<elseif GetCurrentTask() == "get_crampons">>
    Reviens quand tu as trouvé. #shadow:046eb33 
<<elseif !has_item("rope")>>
    Tu n'as pas de corde ! #line:0c18c08 
    <<target rope>>
<<else>>
    <<card ice>>
    Pour marcher sur la glace d'un glacier, nous avons besoin d'un équipement spécial. #line:06d9f34 
    <<card glacier>>
    Que met-on sur ses chaussures pour marcher sur la glace ? #line:076433f 
        -> On met des crampons #line:0b50050
        Exact ! #line:00a7e83 
        <<activity fr08_activity_3 activity_3_done>>
        -> des palmes #line:01a4b20
        Non ! Tu n'es pas à la piscine ! Essaie encore. #line:07c6385 
        <<jump npc_base3>>
<<endif>>

activity_3_done ​


group: base_3
---
<<set $step_base3 = 1>>
<<task_start get_crampons>>
<<SetActive key_gold_3 true>>
<<target chest_3>>

chest_base3 ​


group: base_3
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Le coffre s'ouvre ! Il contient du matériel. #shadow:056ec2b 
    <<trigger chest_3_open>>
    <<SetInteractable chest_3 false>>
    <<SetActive crampons true>>
<<else>>
    Le coffre est fermé à clé. Trouve la clé pour l'ouvrir. #shadow:chest_locked
<<endif>>

item_crampons ​


actor: 
---
<<card crampons>>
Les crampons aident à marcher sur la glace. #line:07102e7 
<<inventory crampons add>>
<<SetActive this false>>
<<task_end get_crampons>>
<<target npc_base3>>
Continue à monter ! #shadow:0a7146f

item_rope ​


actor: 
---
<<card rope>>
La corde permet d'être en sécurité sur la glace et les rochers. #line:038d1bc 
<<inventory rope add>>
<<SetActive this false>>

npc_base4 ​


// ---------------------------------------
// Base 4 - The Top
// ---------------------------------------
group: base_4
color: blue
---
<<card summit>>
Bravo ! Tu es au sommet du Mont Blanc. #line:030fa1c 
Le sommet du Mont-Blanc est à 4807 mètres de hauteur. #line:018880a 
Réponds à trois questions sur la montagne. #line:001e940 
<<jump question_alps>>

question_alps ​


group: base_4
---
Dans quelle montagne est le Mont Blanc ? #line:06f9a2a 
-> Le Mont Blanc est dans les Pyrénées #line:summit_q1_a2
    Ce n'est pas la bonne réponse. Essaie encore. #line:try_again
    <<jump question_alps>>
-> Le Mont Blanc est dans les Carpates #line:summit_q1_a3
    Ce n'est pas la bonne réponse. Essaie encore. #shadow:try_again
    <<jump question_alps>>
-> Le Mont Blanc est dans les Alpes #line:summit_q1_a1
    C'est juste. #line:correct
    <<jump question_height>>
-> Je ne sais pas #line:dontknow #highlight
    Reviens plus tard! #line:comebacklater

question_height ​


group: base_4
---
Quelle est la hauteur du Mont Blanc ? #line:summit_q2
-> 3705 mètres #line:summit_q2_a2
    Ce n'est pas la bonne réponse. Essaie encore. #shadow:try_again
    <<jump question_height>>
-> 4807 mètres #line:summit_q2_a1
    C'est juste. #shadow:correct
    <<jump question_summit_flags>>
-> 5016 mètres #line:summit_q2_a3
    Ce n'est pas la bonne réponse. Essaie encore. #shadow:try_again
    <<jump question_height>>
-> Je ne sais pas #shadow:dontknow #highlight
    Reviens plus tard! #shadow:comebacklater

question_summit_flags ​


group: base_4
---
Quels pays voit-on au sommet du Mont Blanc ? #line:summit_q
-> La France, l'Espagne et l'Allemagne #line:summit_a2
    Ce n'est pas la bonne réponse. Essaie encore ! #line:summit_no
    <<jump question_summit_flags>>
-> La France, l'Italie et la Suisse #line:summit_a1
    Bravo ! Au sommet du Mont Blanc, on voit la France, l'Italie et la Suisse. Maintenant, trouve le drapeau de ces trois pays. #line:summit_ok
    <<activity fr08_match_flags quest_end>>
-> Je ne sais pas #shadow:dontknow #highlight
    Reviens plus tard! #shadow:comebacklater

npc_france ​


tags: 
---
<<card country_france>>
La France est à l'ouest du Mont Blanc. #line:0d23529

npc_italy ​


tags: 
---
<<card country_italy>>
L'Italie est à l'est du Mont Blanc. #line:050fe70

npc_swiss ​


tags: 
---
<<card country_switzerland>>
La Suisse est au nord du Mont Blanc. #line:03db010

snowman_1 ​


// ---------------------------------------
// AREA BONUS
// ---------------------------------------
---
<<if HasCompletedTask("get_hat")>>
    Tu veux de l'aide  pour monter ? #line:0c18060 
        -> Oui, aide-moi s'il te plaît. #line:0f4c405 
        <<teleport base_2>>
        -> Non merci, je reste ici. #line:02a3874
<<else>>
    Reviens plus tard! #shadow:comebacklater
<<endif>>

snowman_2 ​


---
<<if has_item("gloves")>>
    Tu veux de l'aide  pour monter ? #shadow:0c18060 
        -> Oui, aide-moi s'il te plaît. #shadow:0f4c405 
        <<teleport base_3>>
        -> Non merci, je reste ici. #shadow:02a3874 
<<else>>
    Reviens plus tard! #shadow:comebacklater
<<endif>>

snowman_3 ​


---
<<if HasCompletedTask("get_sunglasses")>>
    Tu veux de l'aide  pour monter ? #shadow:0c18060 
        -> Oui, aide-moi s'il te plaît. #shadow:0f4c405 
        <<teleport base_4>>
        -> Non merci, je reste ici. #shadow:02a3874 
<<else>>
    Reviens plus tard! #shadow:comebacklater
<<endif>>

snowman_4 ​


---
Tu veux de l'aide  pour monter ? #shadow:0c18060 
-> Oui, aide-moi s'il te plaît. #shadow:0f4c405 
    <<teleport base_5>>
-> Non merci, je reste ici. #shadow:02a3874

snowman_5 ​


---
<<if HasCompletedTask("get_crampons")>>
    Tu veux de l'aide  pour monter ? #shadow:0c18060 
        -> Oui, aide-moi s'il te plaît. #shadow:0f4c405 
        <<teleport base_6>>
        -> Non merci, je reste ici. #shadow:02a3874 
<<else>>
    Reviens plus tard! #shadow:comebacklater
<<endif>>

snowman_6 ​


---
Tu veux de l'aide  pour monter ? #shadow:0c18060 
-> Oui, aide-moi s'il te plaît. #shadow:0f4c405 
    <<teleport base_7>>
-> Non merci, je reste ici. #shadow:02a3874

snowman_7 ​


---
Tu veux de l'aide  pour monter ? #shadow:0c18060 
-> Oui, aide-moi s'il te plaît. #shadow:0f4c405 
    <<teleport base_1>>
-> Non merci, je reste ici. #shadow:02a3874

marmot ​


color: purple
actor:
group: animals
---
// The marmot makes a sound effect before talking
// <<play_sfx marmot_whistle>>
Je dors tout l'hiver, on dit que j'hiberne. #line:fr08_marmot_2 #card:marmot
J'adore manger des fleurs, des fruits et des herbes. Miam ! #line:fr08_marmot_3 #card:marmot
J'aime me reposer au soleil. #line:fr08_marmot_4 #card:marmot

chest_bonus ​


group: bonus
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Voilà une écharpe bien chaude  ! Prends-la ! #line:003e87c 
    <<trigger chest_bonus_open>>
    <<SetInteractable chest_bonus false>>
    <<SetActive scarf true>>
<<else>>
    Le coffre est fermé à clé. Trouve la clé pour l'ouvrir. #shadow:chest_locked
<<endif>>

item_scarf ​


group: bonus
actor:
color: yellow
---
<<card scarf>>
Avec une écharpe, tu n'as pas froid au cou. #line:0afb2dc 
<<inventory scarf add>>
<<SetActive this false>>

spawned_tourist ​


// ---------------------------------------
// NPCs SPAWNED IN THE SCENE
// these npc are spawn automatically in the scene
// use these to add random facts. everythime you meet them
// they will say one of these lines randomly
color: purple
actor: ADULT_F
spawn_group: tourists 
---
J'aime la montagne. Et toi ? #line:011dc7e 
Le Mont-Blancl est la plus haute montagne de France #line:003ecb2 
Regarde bien ! Tu vas voir une marmotte. #line:04bbada #card:marmot
Pour aller au sommet de Mont-Blanc, prends des vêtements chauds. #line:0590129 
Attention ! La montagne est dangereuse. #line:097ecf0

spawned_hiker ​


color: purple
actor: ADULT_M
spawn_group: hikers
---
A la montagne, il y a de la neige. #line:0557ef5 #card:wind
Regarde bien ! Tu vas voir un bouquetin. #line:0bc67f7 #card:rope
Et toi, tu as déjà fait un bonhomme de neige ? #line:01e5f66 #card:glacier
Pour aller dans la montagne, prends de bonnes chaussures. #line:0dbac73 #card:hiking

spawned_alps_climber ​


color: purple
actor: ADULT_F
spawn_group: alps_climber
---
Le Mont-Blanc est une très belle montagne. #line:0809dce #card:alps
Tu veux aller dans la montagne ? #line:081fbe4 #card:crampons
Un guide de montagne peut venir avec toi. #line:0371d31 #card:mountain_guide