Antura Game Project

Mont Blanc & mountains (fr_08) - Script ​

Educators & Designers: help improving this quest!

Comments and feedback: discuss in the Forum
Improve script translations: comment the Google Sheet
Improve Cards translations: comment the Google Sheet
Improve the script: propose an edit here

quest_start ​


// fr_08 | Mont Blanc
// 
type: panel
color: red
---
<<declare $step_base1 = 0>>
<<declare $step_base2 = 0>>
<<declare $step_base3 = 0>>
<<declare $step_base4 = 0>>
<<SetActive key_gold_intro false>>
<<SetActive key_gold_1 false>>
<<SetActive key_gold_2 false>>
<<SetActive key_gold_3 false>>
<<SetActive backpack false>>
<<SetActive scarf false>>
<<SetActive hat false>>
<<SetActive sunglasses false>>
<<SetActive crampons false>>
<<card alps>>
Welcome to the French Alps! The Alps are high mountains in southeastern France. #line:start_1
<<card place_mont_blanc>>
Today, you are going to the summit of Mont Blanc. It is the highest mountain in France. #line:start_2
<<target npc_intro>>

quest_end ​


type: panel_endgame
color: red
---
<<card place_mont_blanc>>
Well done! You've reached the summit of Mont Blanc. It measures 4807 meters. It's the highest mountain in France. #line:end_1
In the Alps, there are many large and beautiful mountains. #line:end_2
<<jump post_quest_activity>>

post_quest_activity ​


type: panel
tags: proposal
color: red
---
In your notebook, draw Mont Blanc and the flags of France, Switzerland and Italy. #line:post_1
<<quest_end>>

npc_intro ​


// ---------------------------------------
// INTRO
// ---------------------------------------
color: blue
group: intro
---
<<if has_item("backpack")>>
    You have your backpack. Now go get your warm clothes and mountain gear. #line:04c1c1f 
    <<card place_mont_blanc>>
    Climb to the top of Mont Blanc #line:0f4644b 
    <<card climbing>>
    Find warm clothes and mountain gear. #line:07f2699 
    <<SetActive door_intro false>>
    <<target npc_base_1>>
<<elseif GetCurrentTask() == "get_backpack">>
    Come back when you've found it. #line:046eb33 
<<else>>
    <<card mountain_guide>>
    Help me! I'm your mountain guide. A blue dog took your things. #line:0724de3 
    The dog went up into the mountains with your things. #line:01beb5e 
    <<camera_focus camera_mont_blanc>>
    Find warm clothing and mountain gear. #line:0650acc 
    <<card backpack>>
    First, you need a backpack. #line:045409f
    <<camera_focus camera_intro>>
    Open the chest to find the backpack! #line:05cabb5 
    <<task_start get_backpack>>
    <<SetActive key_gold_intro true>>
<<endif>>

chest_intro ​


group: intro
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    The chest opens! Take the backpack. #line:0c1f006 
    <<trigger chest_intro_open>>
    <<SetInteractable chest_intro false>>
    <<SetActive backpack true>>
<<else>>
    The chest is locked. Find the key to open it. #line:chest_locked 
<<endif>>

item_backpack ​


group: intro
actor: 
color: yellow
---
<<card backpack>>
In the backpack, there is water, food, and a map. #line:05e80cb 
<<inventory backpack add>>
<<SetActive this false>>
<<action wear_backpack>>
<<task_end get_backpack>>
Now go to the mountains. Find warm clothes and mountain gear. #line:029f39c
<<target npc_intro>>

npc_base1 ​


// ---------------------------------------
// Base 1 - The Valley's End
// ---------------------------------------
group: base_1
color: blue
---
<<if has_item("coat") and has_item("hat")>>
    Now you're ready. You can go to the summit of Mont Blanc! #line:015bf8a
    <<camera_focus camera_snowman>>
    The snowman can help you. Go see him! #line:showman_help
    <<camera_reset>>
    <<set $step_base1 = 1>>
    <<SetActive door_base_1 false>>
    <<target npc_base_2>>
<<elseif !has_item("coat")>>
    You don't have a coat. Go find it! #line:03dd802 
    <<target coat>>
<<else>>
    <<card wind>>
    It's windy. You need to protect your ears. #line:b1_1
    How to protect your ears? #line:b1_q
    <<activity fr08_activity_1 activity_1_done>>
<<endif>>

activity_1_done ​


group: base_1
---
Open the chest to find the hat! #line:0e83480 #task:get_hat
<<set $step_base1 = 1>>
<<task_start get_hat>>
<<SetActive key_gold_1 true>>
<<target chest_1>>

chest_base1 ​


group: base_1
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    The chest opens! It contains some equipment. #line:056ec2b 
    <<trigger chest_1_open>>
    <<SetInteractable chest_1 false>>
    <<SetActive hat true>>
<<else>>
    The chest is locked. Find the key to open it. #shadow:chest_locked 
<<endif>>

item_coat ​


actor: 
color: yellow
---
<<card coat>>
With a coat, you stay warm when it's windy or snowy. #line:0e23f1f 
<<inventory coat add>>
<<SetActive this false>>

item_hat ​


actor: 
---
<<card hat>>
With a hat, your head won't get cold. #line:000fc05 
The hat protects you from the wind. #line:059d744
<<inventory hat add>>
<<SetActive this false>>
<<task_end get_hat>>
<<target npc_base_1>>
Keep climbing! #line:0a7146f

npc_base2 ​


// ---------------------------------------
// Base 2 - Lower Mid
// ---------------------------------------
group: base_2
color: blue
---
<<if has_item("sunglasses") and has_item("gloves")>>
    Now you're ready. You can go to the summit of Mont Blanc! #shadow:015bf8a
    The snowman can help you. #line:fr08_b2_help
    <<set $step_base2 = 1>>
    <<SetActive door_base_2 false>>
    <<target npc_base_3>>
<<elseif GetCurrentTask() == "get_sunglasses">>
    Come back when you've found it. #shadow:046eb33 
<<elseif !has_item("sunglasses")>>
    <<card sun>>
    The sun and snow hurt your eyes. You need sunglasses. #line:029a03e 
    <<card snow>>
    What protects the eyes? #line:0a70f7d 
    <<activity fr08_activity_2 activity_2_done>>
<<elseif !has_item("gloves")>>
    You don't have any gloves! #line:06b3363 
    <<target gloves>>
<<else>>
    Keep searching. #line:keep_looking
<<endif>>

activity_2_done ​


group: base_2
---
Open the trunk to find the sunglasses! #line:0fdc3cb 
<<set $step_base2 = 1>>
<<task_start get_sunglasses>>
<<SetActive key_gold_2 true>>
<<target chest_2>>

chest_base2 ​


group: base_2
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    The trunk is open! Take out the sunglasses. #line:fr08_b2_chest 
    <<trigger chest_2_open>>
    <<SetInteractable chest_2 false>>
    <<SetActive sunglasses true>>
<<else>>
    The chest is locked. Find the key to open it. #shadow:chest_locked
<<endif>>

item_gloves ​


actor: 
---
<<card gloves>>
The gloves protect the hands. #line:0f2aac7 
It's cold in the mountains #line:0d01879 
<<inventory gloves add>>
<<SetActive this false>>

item_sunglasses ​


actor: 
---
<<card ice>>
In the mountains, the sun and snow hurt the eyes #line:02a2ea9 
<<card sunglasses>>
Sunglasses protect the eyes. #line:088fb7f
<<inventory sunglasses add>>
<<SetActive this false>>
<<task_end get_sunglasses>>
<<target npc_base_2>>
Keep climbing! #shadow:0a7146f

npc_base3 ​


// ---------------------------------------
// Base 3 - High-Mid
// ---------------------------------------
group: base_3
color: blue
---
<<if has_item("crampons") and has_item("rope")>>
    You have your mountain gear. One last effort to reach the summit. #line:06b15bb 
    <<set $step_base3 = 1>>
    <<SetActive door_base_3 false>>
    <<target npc_base4>>
<<elseif GetCurrentTask() == "get_crampons">>
    Come back when you've found it. #shadow:046eb33 
<<elseif !has_item("rope")>>
    You don't have a rope! #line:0c18c08 
    <<target rope>>
<<else>>
    <<card ice>>
    To walk on glacier ice, we need special gear. #line:06d9f34 
    <<card glacier>>
    What do you put on your shoes to walk on ice? #line:076433f 
        -> Crampons #line:0b50050
        Exact! #line:00a7e83 
        <<activity fr08_activity_3 activity_3_done>>
        -> palm fronds #line:01a4b20
        No! You're not at the swimming pool! Try again. #line:07c6385 
        <<jump npc_base3>>
<<endif>>

activity_3_done ​


group: base_3
---
<<set $step_base3 = 1>>
<<task_start get_crampons>>
<<SetActive key_gold_3 true>>
<<target chest_3>>

chest_base3 ​


group: base_3
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    The chest opens! It contains some equipment. #shadow:056ec2b 
    <<trigger chest_3_open>>
    <<SetInteractable chest_3 false>>
    <<SetActive crampons true>>
<<else>>
    The chest is locked. Find the key to open it. #shadow:chest_locked
<<endif>>

item_crampons ​


actor: 
---
<<card crampons>>
Crampons help you walk on ice. #line:07102e7 
<<inventory crampons add>>
<<SetActive this false>>
<<task_end get_crampons>>
<<target npc_base3>>
Keep climbing! #shadow:0a7146f

item_rope ​


actor: 
---
<<card rope>>
The rope allows you to be safe on ice and rocks. #line:038d1bc 
<<inventory rope add>>
<<SetActive this false>>

npc_base4 ​


// ---------------------------------------
// Base 4 - The Top
// ---------------------------------------
group: base_4
color: blue
---
<<card summit>>
Well done! You've reached the summit of Mont Blanc. #line:030fa1c 
The summit of Mont Blanc is 4807 meters high. #line:018880a 
Answer three questions about the mountain. #line:001e940 
<<jump question_alps>>

question_alps ​


group: base_4
---
In which mountain range is Mont Blanc located? #line:06f9a2a 
-> Mont Blanc is in the Pyrenees #line:summit_q1_a2
    That's not the right answer. Try again. #line:try_again
    <<jump question_alps>>
-> Mont Blanc is in the Carpathians #line:summit_q1_a3
    That's not the right answer. Try again. #shadow:try_again
    <<jump question_alps>>
-> Mont Blanc is in the Alps #line:summit_q1_a1
    That's right. #line:correct
    <<jump question_height>>
-> I don't know #line:dontknow #highlight
    Come back later! #line:comebacklater

question_height ​


group: base_4
---
What is the height of Mont Blanc? #line:summit_q2
-> 3705 meters #line:summit_q2_a2
    That's not the right answer. Try again. #shadow:try_again
    <<jump question_height>>
-> 4807 meters #line:summit_q2_a1
    That's right. #shadow:correct
    <<jump question_summit_flags>>
-> 5016 meters #line:summit_q2_a3
    That's not the right answer. Try again. #shadow:try_again
    <<jump question_height>>
-> I don't know #shadow:dontknow #highlight
    Come back later! #shadow:comebacklater

question_summit_flags ​


group: base_4
---
What countries can be seen from the summit of Mont Blanc? #line:summit_q
-> France, Spain and Germany #line:summit_a2
    That's not the right answer. Try again! #line:summit_no
    <<jump question_summit_flags>>
-> France, Italy and Switzerland #line:summit_a1
    Well done! From the summit of Mont Blanc, you can see France, Italy, and Switzerland. Now, find the flag of these three countries. #line:summit_ok
    <<activity fr08_match_flags quest_end>>
-> I don't know #shadow:dontknow #highlight
    Come back later! #shadow:comebacklater

npc_france ​


tags: 
---
<<card country_france>>
France is west of Mont Blanc. #line:0d23529

npc_italy ​


tags: 
---
<<card country_italy>>
Italy is east of Mont Blanc. #line:050fe70

npc_swiss ​


tags: 
---
<<card country_switzerland>>
Switzerland is north of Mont Blanc. #line:03db010

snowman_1 ​


// ---------------------------------------
// AREA BONUS
// ---------------------------------------
---
<<if HasCompletedTask("get_hat")>>
    Do you need help getting on? #line:0c18060 
        -> Yes, please help me. #line:0f4c405 
        <<teleport base_2>>
        -> No thanks, I'll stay here. #line:02a3874
<<else>>
    Come back later! #shadow:comebacklater
<<endif>>

snowman_2 ​


---
<<if has_item("gloves")>>
    Do you need help getting on? #shadow:0c18060 
        -> Yes, please help me. #shadow:0f4c405 
        <<teleport base_3>>
        -> No thanks, I'll stay here. #shadow:02a3874 
<<else>>
    Come back later! #shadow:comebacklater
<<endif>>

snowman_3 ​


---
<<if HasCompletedTask("get_sunglasses")>>
    Do you need help getting on? #shadow:0c18060 
        -> Yes, please help me. #shadow:0f4c405 
        <<teleport base_4>>
        -> No thanks, I'll stay here. #shadow:02a3874 
<<else>>
    Come back later! #shadow:comebacklater
<<endif>>

snowman_4 ​


---
Do you need help getting on? #shadow:0c18060 
-> Yes, please help me. #shadow:0f4c405 
    <<teleport base_5>>
-> No thanks, I'll stay here. #shadow:02a3874

snowman_5 ​


---
<<if HasCompletedTask("get_crampons")>>
    Do you need help getting on? #shadow:0c18060 
        -> Yes, please help me. #shadow:0f4c405 
        <<teleport base_6>>
        -> No thanks, I'll stay here. #shadow:02a3874 
<<else>>
    Come back later! #shadow:comebacklater
<<endif>>

snowman_6 ​


---
Do you need help getting on? #shadow:0c18060 
-> Yes, please help me. #shadow:0f4c405 
    <<teleport base_7>>
-> No thanks, I'll stay here. #shadow:02a3874

snowman_7 ​


---
Do you need help getting on? #shadow:0c18060 
-> Yes, please help me. #shadow:0f4c405 
    <<teleport base_1>>
-> No thanks, I'll stay here. #shadow:02a3874

marmot ​


color: purple
actor:
group: animals
---
// The marmot makes a sound effect before talking
// <<play_sfx marmot_whistle>>
I sleep all winter, they say I hibernate. #line:fr08_marmot_2 #card:marmot
I love eating flowers, fruits, and herbs. Yum! #line:fr08_marmot_3 #card:marmot
I like to relax in the sun. #line:fr08_marmot_4 #card:marmot

chest_bonus ​


group: bonus
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Here's a nice warm scarf! Take it! #line:003e87c 
    <<trigger chest_bonus_open>>
    <<SetInteractable chest_bonus false>>
    <<SetActive scarf true>>
<<else>>
    The chest is locked. Find the key to open it. #shadow:chest_locked
<<endif>>

item_scarf ​


group: bonus
actor:
color: yellow
---
<<card scarf>>
With a scarf, your neck won't get cold. #line:0afb2dc 
<<inventory scarf add>>
<<SetActive this false>>

spawned_tourist ​


// ---------------------------------------
// NPCs SPAWNED IN THE SCENE
// these npc are spawn automatically in the scene
// use these to add random facts. everythime you meet them
// they will say one of these lines randomly
color: purple
actor: ADULT_F
spawn_group: tourists 
---
I love the mountains. And you? #line:011dc7e 
Mont Blanc is the highest mountain in France. #line:003ecb2 
Look closely! You're going to see a marmot. #line:04bbada #card:marmot
To go to the summit of Mont Blanc, take warm clothes. #line:0590129 
Warning! The mountain is dangerous. #line:097ecf0

spawned_hiker ​


color: purple
actor: ADULT_M
spawn_group: hikers
---
There is snow in the mountains. #line:0557ef5 #card:wind
Look closely! You're going to see an ibex. #line:0bc67f7 #card:rope
Have you ever made a snowman? #line:01e5f66 #card:glacier
To go into the mountains, take good shoes. #line:0dbac73 #card:hiking

spawned_alps_climber ​


color: purple
actor: ADULT_F
spawn_group: alps_climber
---
Mont Blanc is a very beautiful mountain. #line:0809dce #card:alps
Do you want to go to the mountains? #line:081fbe4 #card:crampons
A mountain guide can come with you. #line:0371d31 #card:mountain_guide