Mont Blanc i góry (fr_08) - Script

Educators & Designers: help improving this quest!

Comments and feedback: discuss in the Forum
Improve script translations: comment the Google Sheet
Improve Cards translations: comment the Google Sheet
Improve the script: propose an edit here

quest_start

// fr_08 | Mont Blanc
// 
type: panel
color: red
---
<<declare $step_base1 = 0>>
<<declare $step_base2 = 0>>
<<declare $step_base3 = 0>>
<<declare $step_base4 = 0>>
<<SetActive key_gold_intro false>>
<<SetActive key_gold_1 false>>
<<SetActive key_gold_2 false>>
<<SetActive key_gold_3 false>>
<<SetActive backpack false>>
<<SetActive scarf false>>
<<SetActive hat false>>
<<SetActive sunglasses false>>
<<SetActive crampons false>>
<<card alps>>
Witamy w Alpach Francuskich! #line:start_1
<<card place_mont_blanc>>
Dzisiaj wspinamy się na Mont Blanc. To najwyższy szczyt Alp. #line:start_2
<<target npc_intro>>

quest_end

type: panel_endgame
color: red
---
<<card place_mont_blanc>>
Niesamowite! Dotarłeś na szczyt Mont Blanc. Ma 4807 metrów wysokości! #line:end_1
Alpy są pełne wysokich, pięknych gór. #line:end_2
<<jump post_quest_activity>>

post_quest_activity

type: panel
tags: proposal
color: red
---
Narysuj Mont Blanc i trzy flagi w swoim zeszycie! #line:post_1
<<quest_end>>

npc_intro

// ---------------------------------------
// INTRO
// ---------------------------------------
color: blue
group: intro
---
<<if has_item("backpack")>>
    Widzę, że masz plecak. Możesz iść! #line:04c1c1f 
    <<card place_mont_blanc>>
    Wejdźmy na Mont Blanc. #line:0f4644b 
    <<card climbing>>
    Znajdź cały sprzęt wspinaczkowy i dowiedz się więcej o trzech pobliskich krajach! #line:07f2699 
    <<SetActive door_intro false>>
    <<target npc_base_1>>
<<elseif GetCurrentTask() == "get_backpack">>
    Wróć, gdy skończysz zadanie. #line:046eb33 
<<else>>
    <<card mountain_guide>>
    Ratunku! Jestem przewodnikiem górskim. Niebieski pies zabrał nasz sprzęt wspinaczkowy! #line:0724de3 
    Widzieliśmy psa wbiegającego na górę. #line:01beb5e 
    <<camera_focus camera_mont_blanc>>
    Zapraszamy do eksploracji Mont Blanc i zapoznania się z naszym sprzętem. #line:0650acc 
    <<card backpack>>
    Przed wyjazdem będziesz potrzebować plecaka. #line:045409f
    <<camera_focus camera_intro>>
    Rozejrzyj się dookoła! #line:05cabb5 
    <<task_start get_backpack>>
    <<SetActive key_gold_intro true>>
<<endif>>

chest_intro

group: intro
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Otwiera się! Jest w nim plecak. #line:0c1f006 
    <<trigger chest_intro_open>>
    <<SetInteractable chest_intro false>>
    <<SetActive backpack true>>
<<else>>
    Jest zamknięte. Może potrzebujesz klucza. #line:chest_locked 
<<endif>>

item_backpack

group: intro
actor: 
color: yellow
---
<<card backpack>>
W tym plecaku można przenosić jedzenie, wodę i mapę. #line:05e80cb 
<<inventory backpack add>>
<<SetActive this false>>
<<action wear_backpack>>
<<task_end get_backpack>>
Teraz możemy opuścić obóz bazowy i rozpocząć przygodę! #line:029f39c
<<target npc_intro>>

npc_base1

// ---------------------------------------
// Base 1 - The Valley's End
// ---------------------------------------
group: base_1
color: blue
---
<<if has_item("coat") and has_item("hat")>>
    Jesteś teraz gotowy do wspinaczki! #line:015bf8a
    <<camera_focus camera_snowman>>
    Jeśli masz blokadę, bałwan może Ci pomóc! #line:showman_help
    <<camera_reset>>
    <<set $step_base1 = 1>>
    <<SetActive door_base_1 false>>
    <<target npc_base_2>>
<<elseif !has_item("coat")>>
    Brakuje Ci płaszcza! #line:03dd802 
    <<target coat>>
<<else>>
    <<card wind>>
    Zaczyna wiać wiatr. Moje uszy potrzebują ochrony! #line:b1_1
    Jak chronić uszy, gdy wieje silny wiatr? #line:b1_q
    <<activity fr08_activity_1 activity_1_done>>
<<endif>>

activity_1_done

group: base_1
---
Otwórz skrzynię i wyjmij ciepłą czapkę! #line:0e83480 #task:get_hat
<<set $step_base1 = 1>>
<<task_start get_hat>>
<<SetActive key_gold_1 true>>
<<target chest_1>>

chest_base1

group: base_1
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Otwiera się! Zawiera trochę sprzętu. #line:056ec2b 
    <<trigger chest_1_open>>
    <<SetInteractable chest_1 false>>
    <<SetActive hat true>>
<<else>>
    Jest zamknięte. Może potrzebujesz klucza. #shadow:chest_locked 
<<endif>>

item_coat

actor: 
color: yellow
---
<<card coat>>
Ten płaszcz zapewni Ci ciepło w czasie wiatru i śniegu. #line:0e23f1f 
<<inventory coat add>>
<<SetActive this false>>

item_hat

actor: 
---
<<card hat>>
Ciepła czapka utrzymuje ciepło głowy. #line:000fc05 
Pomaga również, gdy wieje zimny wiatr. #line:059d744
<<inventory hat add>>
<<SetActive this false>>
<<task_end get_hat>>
<<target npc_base_1>>
Teraz możesz kontynuować wspinaczkę! #line:0a7146f 

npc_base2

// ---------------------------------------
// Base 2 - Lower Mid
// ---------------------------------------
group: base_2
color: blue
---
<<if has_item("sunglasses") and has_item("gloves")>>
    Jesteś teraz gotowy do wspinaczki! #shadow:015bf8a
    Jeśli utkniesz, bałwan może Ci pomóc! #line:fr08_b2_help
    <<set $step_base2 = 1>>
    <<SetActive door_base_2 false>>
    <<target npc_base_3>>
<<elseif GetCurrentTask() == "get_sunglasses">>
    Wróć, gdy skończysz zadanie. #shadow:046eb33 
<<elseif !has_item("sunglasses")>>
    <<card sun>>
    Słońce mocno świeci na śniegu. Potrzebujemy ochrony oczu. #line:029a03e 
    <<card snow>>
    Co chroni Twoje oczy przed jaskrawym śniegiem i słońcem? #line:0a70f7d 
    <<activity fr08_activity_2 activity_2_done>>
<<elseif !has_item("gloves")>>
    Brakuje Ci rękawiczek! #line:06b3363 
    <<target gloves>>
<<else>>
    Szukaj dalej. Nadal potrzebujemy całego sprzętu. #line:keep_looking
<<endif>>

activity_2_done

group: base_2
---
Otwórz skrzynię i wyjmij okulary przeciwsłoneczne! #line:0fdc3cb 
<<set $step_base2 = 1>>
<<task_start get_sunglasses>>
<<SetActive key_gold_2 true>>
<<target chest_2>>

chest_base2

group: base_2
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Otwiera się! W środku są okulary przeciwsłoneczne. #line:fr08_b2_chest 
    <<trigger chest_2_open>>
    <<SetInteractable chest_2 false>>
    <<SetActive sunglasses true>>
<<else>>
    Jest zamknięte. Może potrzebujesz klucza. #shadow:chest_locked
<<endif>>

item_gloves

actor: 
---
<<card gloves>>
Rękawiczki utrzymują palce w cieple i suchości. #line:0f2aac7 
Zimne ręce utrudniają wspinaczkę. #line:0d01879 
<<inventory gloves add>>
<<SetActive this false>>

item_sunglasses

actor: 
---
<<card ice>>
Śnieg i lód odbijają jasne światło słoneczne. #line:02a2ea9 
<<card sunglasses>>
Okulary przeciwsłoneczne chronią oczy. #line:088fb7f
<<inventory sunglasses add>>
<<SetActive this false>>
<<task_end get_sunglasses>>
<<target npc_base_2>>
Teraz możesz kontynuować wspinaczkę! #shadow:0a7146f 

npc_base3

// ---------------------------------------
// Base 3 - High-Mid
// ---------------------------------------
group: base_3
color: blue
---
<<if has_item("crampons") and has_item("rope")>>
    Masz sprzęt lodowy. Ostatni atak na szczyt! #line:06b15bb 
    <<set $step_base3 = 1>>
    <<SetActive door_base_3 false>>
    <<target npc_base4>>
<<elseif GetCurrentTask() == "get_crampons">>
    Wróć, gdy skończysz zadanie. #shadow:046eb33 
<<elseif !has_item("rope")>>
    Brakuje ci liny! #line:0c18c08 
    <<target rope>>
<<else>>
    <<card ice>>
    Aby chodzić po lodowcu, potrzebujemy specjalnego sprzętu. #line:06d9f34 
    <<card glacier>>
    Co zakładasz do butów, żeby chodzić po lodzie i się nie ślizgać? #line:076433f 
        -> Raki #line:0b50050 
        Dobrze! Użyj ich, żeby utrzymać równowagę. #line:00a7e83 
        <<activity fr08_activity_3 activity_3_done>>
        -> Płetwy #line:01a4b20 
        Nie! Nie pływasz! Spróbuj ponownie. #line:07c6385 
        <<jump npc_base3>>
<<endif>>

activity_3_done

group: base_3
---
Otwórz skrzynię, aby wyjąć raki! #line:02c9805 
<<set $step_base3 = 1>>
<<task_start get_crampons>>
<<SetActive key_gold_3 true>>
<<target chest_3>>

chest_base3

group: base_3
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Otwiera się! Zawiera trochę sprzętu. #shadow:056ec2b 
    <<trigger chest_3_open>>
    <<SetInteractable chest_3 false>>
    <<SetActive crampons true>>
<<else>>
    Jest zamknięte. Może potrzebujesz klucza. #shadow:chest_locked
<<endif>>

item_crampons

actor: 
---
<<card crampons>>
Pomagają bezpiecznie chodzić po lodzie. #line:07102e7 
<<inventory crampons add>>
<<SetActive this false>>
<<task_end get_crampons>>
<<target npc_base3>>
Teraz możesz kontynuować wspinaczkę! #shadow:0a7146f 

item_rope

actor: 
---
<<card rope>>
Lina pomaga wspinaczom zachować bezpieczeństwo na lodzie i skałach. #line:038d1bc 
<<inventory rope add>>
<<SetActive this false>>

npc_base4

// ---------------------------------------
// Base 4 - The Top
// ---------------------------------------
group: base_4
color: blue
---
<<card summit>>
Udało się! Jesteśmy na szczycie Mont Blanc. #line:030fa1c 
Wysokość tego szczytu wynosi 4807 metrów. #line:018880a 
Przed grą o flagę odpowiedzmy na trzy pytania dotyczące gór. #line:001e940 
<<jump question_alps>>

question_alps

group: base_4
---
W jakim paśmie górskim znajduje się Mont Blanc? #line:06f9a2a 
-> Pireneje #line:summit_q1_a2
    Nie do końca. Spróbuj ponownie. #line:try_again
    <<jump question_alps>>
-> Apeniny #line:summit_q1_a3
    Nie do końca. Spróbuj ponownie. #shadow:try_again
    <<jump question_alps>>
-> Alpy #line:summit_q1_a1
    Prawidłowy! #line:correct
    <<jump question_height>>
-> Nie wiem #line:dontknow #highlight
    Wróć później! #line:comebacklater

question_height

group: base_4
---
Jak wysoki jest Mont Blanc? #line:summit_q2
-> 3705 metrów #line:summit_q2_a2
    Nie do końca. Spróbuj ponownie. #shadow:try_again
    <<jump question_height>>
-> 4807 metrów #line:summit_q2_a1
    Prawidłowy! #shadow:correct
    <<jump question_summit_flags>>
-> 5016 metrów #line:summit_q2_a3
    Nie do końca. Spróbuj ponownie. #shadow:try_again
    <<jump question_height>>
-> Nie wiem #shadow:dontknow #highlight
    Wróć później! #shadow:comebacklater

question_summit_flags

group: base_4
---
Jakie kraje widać stąd? #line:summit_q
-> Francja, Hiszpania i Niemcy #line:summit_a2
    Nie do końca. To trochę za daleko! #line:summit_no
    <<jump question_summit_flags>>
-> Francja, Włochy i Szwajcaria #line:summit_a1
    Dobrze! Rozwieśmy flagi. #line:summit_ok
    <<activity fr08_match_flags quest_end>>
-> Alpy #shadow:summit_q1_a1
    Wróć później! #shadow:comebacklater
-> Nie wiem #shadow:dontknow #highlight
    Wróć później! #shadow:comebacklater

npc_france

tags: 
---
<<card country_france>>
Francja leży na zachód od Mont Blanc. #line:0d23529 

npc_italy

tags: 
---
<<card country_italy>>
Włochy leżą na wschód od Mont Blanc. #line:050fe70  

npc_swiss

tags: 
---
<<card country_switzerland>>
Szwajcaria leży na północ od Mont Blanc. #line:03db010  

snowman_1

// ---------------------------------------
// AREA BONUS
// ---------------------------------------
---
<<if HasCompletedTask("get_hat")>>
    Potrzebujesz pomocy we wspięciu się na górę? #line:0c18060 
        -> Tak #line:0f4c405 
        <<teleport base_2>>
        -> Nie, zostaję tutaj #line:02a3874
<<else>>
    Wróć później! #shadow:comebacklater
<<endif>>

snowman_2

---
<<if has_item("gloves")>>
    Potrzebujesz pomocy we wspięciu się na górę? #shadow:0c18060 
        -> Tak #shadow:0f4c405 
        <<teleport base_3>>
        -> Nie, zostaję tutaj #shadow:02a3874 
<<else>>
    Wróć później! #shadow:comebacklater
<<endif>>

snowman_3

---
<<if HasCompletedTask("get_sunglasses")>>
    Potrzebujesz pomocy we wspięciu się na górę? #shadow:0c18060 
        -> Tak #shadow:0f4c405 
        <<teleport base_4>>
        -> Nie, zostaję tutaj #shadow:02a3874 
<<else>>
    Wróć później! #shadow:comebacklater
<<endif>>

snowman_4

---
Potrzebujesz pomocy we wspięciu się na górę? #shadow:0c18060 
-> Tak #shadow:0f4c405 
    <<teleport base_5>>
-> Nie, zostaję tutaj #shadow:02a3874 

snowman_5

---
<<if HasCompletedTask("get_crampons")>>
    Potrzebujesz pomocy we wspięciu się na górę? #shadow:0c18060 
        -> Tak #shadow:0f4c405 
        <<teleport base_6>>
        -> Nie, zostaję tutaj #shadow:02a3874 
<<else>>
    Wróć później! #shadow:comebacklater
<<endif>>

snowman_6

---
Potrzebujesz pomocy we wspięciu się na górę? #shadow:0c18060 
-> Tak #shadow:0f4c405 
    <<teleport base_7>>
-> Nie, zostaję tutaj #shadow:02a3874 

snowman_7

---
Potrzebujesz pomocy we wspięciu się na górę? #shadow:0c18060 
-> Tak #shadow:0f4c405 
    <<teleport base_1>>
-> Nie, zostaję tutaj #shadow:02a3874 

marmot

color: purple
actor:
group: animals
---
// The marmot makes a sound effect before talking
// <<play_sfx marmot_whistle>>
Całą zimę śpię pod śniegiem. To się nazywa hibernacja! #line:fr08_marmot_2 #card:marmot
Uwielbiam jeść alpejskie kwiaty i trawę. Pycha! #line:fr08_marmot_3 #card:marmot
Nie zwracajcie na mnie uwagi, po prostu opalam się na tej ciepłej skale. #line:fr08_marmot_4 #card:marmot

chest_bonus

group: bonus
---
<<if has_item("key_gold")>>
    <<inventory key_gold remove>>
    Znalazłeś ciepły szalik! #line:003e87c 
    <<trigger chest_bonus_open>>
    <<SetInteractable chest_bonus false>>
    <<SetActive scarf true>>
<<else>>
    Jest zamknięte. Może potrzebujesz klucza. #shadow:chest_locked
<<endif>>

item_scarf

group: bonus
actor:
color: yellow
---
<<card scarf>>
Szalik chroni przed wiatrem na szyi. #line:0afb2dc 
<<inventory scarf add>>
<<SetActive this false>>

spawned_tourist

// ---------------------------------------
// NPCs SPAWNED IN THE SCENE
// these npc are spawn automatically in the scene
// use these to add random facts. everythime you meet them
// they will say one of these lines randomly
color: purple
actor: ADULT_F
spawn_group: tourists 
---
Uwielbiam góry! #line:011dc7e 
Mont Blanc jest najwyższą górą w Alpach! #line:003ecb2 
Mam nadzieję zobaczyć świstaka! #line:04bbada #card:marmot
Nie zapomnij zabrać ciepłych ubrań! #line:0590129 
Góry mogą być niebezpieczne, więc bądź ostrożny! #line:097ecf0 

spawned_hiker

color: purple
actor: ADULT_M
spawn_group: hikers
---
Do pieszych wędrówek tutaj potrzebne są dobre buty. #line:0dbac73 #card:hiking
Wiatr może się szybko zmienić. #line:0557ef5 #card:wind
Gdy jest ślisko, podążam za liną. #line:0bc67f7 #card:rope
Ten lodowiec wygląda jak zamarznięta rzeka. #line:01e5f66 #card:glacier

spawned_alps_climber

color: purple
actor: ADULT_F
spawn_group: alps_climber
---
Uwielbiam wspinaczkę w Alpach. #line:0809dce #card:alps
Raki pomagają mi chodzić po twardym lodzie. #line:081fbe4 #card:crampons
Wspinaczka z przewodnikiem jest bezpieczniejsza. #line:0371d31 #card:mountain_guide